#e
#Title[zNu남ڂ̗Vjev]
#Text[]
#ScriptVersion[2]

script_enemy_main
{
	let scroll=0;
	let flag=0;
	let cx=GetCenterX();
	let cy=GetCenterY();
	let boss=GetCurrentScriptDirectory~"img\boss7-2.png";
	let eye=GetCurrentScriptDirectory~"img\bg7-1.png";
	let asa=GetCurrentScriptDirectory~"img\bg7-2.png";
	LoadUserShotData(GetCurrentScriptDirectory~"shot.txt");
	@Initialize
	{
		SetScore(30000);
		SetLife(400);
		SetDamageRate(10,0);
		SetMovePosition02(cx,cy-120,60);
		SetTimer(80);
		SetInvincibility(60);
		LoadGraphic(boss);
		LoadGraphic(eye);
		LoadGraphic(asa);
		LoadGraphic(GetCurrentScriptDirectory~".\img\shot\bullet.png");
		shottask;
		movetask;
		drawtask;
		bombtask;
		CutIn(YOUMU,"zNu남ڂ̗Vjev",0,0,0,0,0);
	}
	@MainLoop
	{
		yield;
	}
	@Finalize
	{
		loop(16)
		{
			CreateItem(ITEM_SCORE,GetX+rand(-30,30),GetY+rand(-30,30));
		}
		DeleteGraphic(boss);
		DeleteGraphic(eye);
		DeleteGraphic(asa);
		DeleteGraphic(GetCurrentScriptDirectory~".\img\shot\bullet.png");
	}
	@DrawLoop
	{
		SetTexture(boss);	
		if(flag==1)
		{
			SetGraphicRect(52,0,81,63);
		}
		else if(flag==2)
		{
			SetGraphicRect(24,0,52,63);
		}
		else
		{
			SetGraphicRect(0,0,24,63);
		}
		SetGraphicScale(1,1);
		SetGraphicAngle(0,0,0);
		DrawGraphic(GetX,GetY);
	}
	@BackGround
	{
		SetColor(128,128,128);
		SetTexture(eye);	
		SetGraphicRect(0,0,384,448);
		SetAlpha(255);
		SetGraphicScale(1,1);
		SetGraphicAngle(0,0,0);
		DrawGraphic(cx,cy);
		SetColor(255,255,255);
		SetTexture(asa);	
		SetGraphicRect(0,0,888,189*5);
		SetAlpha(64);
		SetGraphicScale(0.5,0.75);
		SetGraphicAngle(0,0,0);
		DrawGraphic(cx+scroll,cy);
		DrawGraphic(cx+scroll-444,cy);
		if(scroll>444)
		{
			scroll=0;
		}
	}
	task shottask
	{
		wait(120);
		let angle=0;
		loop
		{
			loop(20)
			{
				CreateObjLaser(GetX,GetY,angle,30,8,BLUE02,1);
				CreateObjShot(GetX,GetY,angle+30,155,1);
				angle+=140;
				wait(3);
			}
			loop(20)
			{
				CreateObjLaser(GetX,GetY,angle,30,8,BLUE02,-1);
				CreateObjShot(GetX,GetY,angle+30,155,-1);
				angle-=140;
				wait(3);
			}
			wait(60);
		}
	}
	task movetask
	{
		wait(120);
		loop
		{
			wait(120);
			move(rand(40, 80), rand(-40, 40), 60,GetClipMinX + 32, GetClipMinY + 80,GetClipMaxX - 32, GetClipMinY + 160);
			wait(60);
		}
	}
	task drawtask
	{
		let x=0;
		loop
		{	
			if(GetX>x+0.5)
			{
				flag=1;
			}
			else if(GetX<x-0.5)
			{
				flag=2;
			}
			else
			{
				flag=0;
			}
			x=GetX;
			scroll++;
			yield;
		}
	}
	task bombtask
	{
		loop
		{
			if(OnBomb)
			{
				SetAlpha(64);
				SetDamageRate(0,0);
			}
			else
			{
				SetAlpha(255);
				SetDamageRate(10,0);
				SetCollisionA(GetX(),GetY(),24);
				SetCollisionB(GetX(),GetY(),24);
			}
			yield;
		}
	}
	task CreateObjLaser(let x, let y, let angle, let length,let width, let graphic,let angle2)
	{
		let count=0;
		let speed=1;
		let obj = Obj_Create(OBJ_SINUATE_LASER);
		Obj_SetPosition(obj, x, y);
		Obj_SetAngle(obj, angle);
		ObjShot_SetGraphic(obj, graphic);
		ObjShot_SetDelay(obj, 5);
		ObjSinuateLaser_SetLength(obj, length);
		ObjSinuateLaser_SetWidth(obj, width);
		while(!Obj_BeDeleted(obj))
		{
			Obj_SetAngle(obj, angle);
			Obj_SetSpeed(obj,speed);
			if(count<120)
			{
				angle+=angle2;
			}
			if(speed<6)
			{
				speed+=0.06;
			}
			count++;
			yield;
		}
	}
	task CreateObjShot(let x, let y, let angle,let graphic,let angle2)
	{
		let count=0;
		let speed=1;
		let obj = Obj_Create(OBJ_SHOT);
		Obj_SetPosition(obj, x, y);
		Obj_SetAngle(obj, angle);
		ObjShot_SetGraphic(obj, graphic);
		ObjShot_SetDelay(obj, 5);
		while(!Obj_BeDeleted(obj))
		{
			Obj_SetAngle(obj, angle);
			Obj_SetSpeed(obj,speed);
			if(count<120)
			{
				angle+=angle2;
			}
			if(speed<6)
			{
				speed+=0.06;
			}
			count++;
			yield;
		}
	}
	function move(xMove, yAdd, frame, left, top, right, bottom)
	{
		let x;
		let y;
		if(GetPlayerX < GetX) 
		{
			x = GetX - xMove;
			if(x < left) 
			{
				x = GetX + xMove;
			}
		} 
		else {
			x = GetX + xMove;
			if(right < x)
			{
				x = GetX - xMove;
			}
		}
		y = GetY + yAdd;
		if(y < top)
		{
			y = top;
		}
		else if(bottom < y)
		{
			y = bottom;
		}
		SetMovePosition02(x, y, frame);
	}
	function wait(w) 
	{
		loop(w)
		{
			yield;
		}
	}
}
